Kako stvoriti aplikaciju za praćenje vremena u sustavu Windows pomoću AutoHotKey

Svaki dan rano počinjete s poslom kako biste sve riješili tijekom dana. Zatim pogledate na sat i 3 su ujutro, ali vaš posao još uvijek nije gotov. Pa gdje je nestalo vrijeme?

Možete koristiti namjensku aplikaciju za praćenje vremena, ali one mogu biti komplicirane i frustrirajuće. Umjesto toga, zašto ne izradite vlastitu jednostavnu malu aplikaciju? Ova aplikacija može pratiti sve prozore koje ste koristili tijekom dana. Trebate samo AutoHotKey, osnovni program za obradu teksta kao što je Notepad, i oko pola sata. Započnimo!

Stvorite vlastitu Windows skriptu za bilježenje pomoću AutoHotKey

Prije početka trebali biste instalirati AHK na svoje računalo jer će djelovati kao "parser" za skriptu. To je alat koji će vašoj skripti omogućiti "pokretanje".

Napomena : možete također kompajlirati skriptu nakon završetka kako biste je pretvorili u pravi izvršni program. Međutim, to je izvan dosega ovog članka.

Preuzmite AutoHotKey sa službene web stranice i instalirajte ga.

Odaberite Novo > AutoHotKey skripta

Pokrenite svoj omiljeni upravitelj datoteka i pristupite mapi u koju želite pohraniti skriptu. Zatim desnom tipkom miša kliknite prazno mjesto i odaberite Novo > AutoHotKey skripta .

Kada završite, vrijeme je da napišete pravi scenarij.

1. Identificirajte potrebne varijable

Otvorite skriptu u svom omiljenom editoru. Možete koristiti nešto jednostavno kao što je Notepad koji dolazi sa sustavom Windows, ali članak će koristiti Notepad++  za ovaj vodič. Notepad++ je besplatan i bolje prilagođen za ovu namjenu, stoga biste ga trebali isprobati.

Imajte na umu da ne biste trebali koristiti aplikacije kao što su Word ili Google Docs, koje mogu utjecati na formatiranje skripte. Koristite uređivač teksta ili koda.

Skripta će sadržavati neke osnovne preporučene informacije o kompatibilnosti i izvedbi. Ostavite ih kakvi jesu i pokrenite skriptu u nastavku.

Počinje sa:

AppLoggingRate = 10 ; Time interval (in seconds) between active window title captures.
SleepTime := AppLoggingRate * 1000
LogPath = %A_ScriptDir%
LastActiveWindow =

Započnite dodjeljivanjem vrijednosti "10" AppLoggingRate , koja će se koristiti za izračunavanje vremena između pokušaja zapisivanja prozora.

Kada se koristi s AHK-ovom funkcijom mirovanja, 1000 je otprilike jednako jednoj sekundi. Dakle, množenjem s AppLogingRate učinit ćete varijablu SleepTime "jednakom 10 sekundi".

LogPath je staza koja se koristi za pohranu zapisa. Primjer koristi vrijednost %A_ScriptDir% , što se prevodi kao "direktorij iz kojeg pokrećete skriptu". Možete koristiti puni put do druge mape ako želite.

Na kraju, postavite LastActiveWindow na prazno i ​​kasnije ga koristite za provjeru je li se aktivni prozor promijenio.

2. Pratite aktivne prozore

Budući da želimo kontinuirano pratiti koji je prozor aktivan i ako se mijenja, zabilježiti naslov i vrijeme, morat ćemo koristiti “petlju”.

Kao što ime sugerira, petlja radi kontinuirano, ponavljajući iste funkcije. Zahvaljujući jednostavnoj sintaksi AHK-a, sljedeći "kod" je relativno lako razumjeti:

Loop
{
    Sleep %SleepTime%
    Msgbox, It Works!
}

Definirajte petlju tako da jednostavno upišete riječ "petlja" i označite početak s "{" , a završetak s "}". Sve u redovima između "{" i "}" radit će zauvijek dok ne izađete iz skripte.

Započnite petlju čekanjem ( Sleep ) na količinu vremena koja je jednaka varijabli SleepTime. Ova varijabla čini kontrolu vremena jednostavnijom. Umjesto da sami uređujete skriptu, možete joj putem ove varijable "reći" koliko sekundi svaka petlja treba trajati.

Na kraju, upotrijebite okvir za poruke za testiranje skripte. Pokušajte ga spremiti i pokrenuti (dvaput kliknite na datoteku skripte). Vidjet ćete okvir s porukom "Radi!" (skripta radi) nakon 10 sekundi.

Desnom tipkom miša kliknite ikonu AHK-a u traci sustava Windows i izađite iz skripte kada budete imali dovoljno okvira s porukama. Zatim se vratite u uređivač i zamijenite redak MsgBox s:

WinGetActiveTitle, ActiveWindow

Ovo je naredba za dobivanje naslova aktivnog prozora. Izostavite dodatni redak "StoreActiveWindow" koji je primjer koristio tijekom skriptiranja za testiranje.

Dobijte naslov aktivnog prozora i pohranite ga u varijablu

3. Dobijte trenutno vrijeme i ime

Sada dolazi srž logike scenarija. Usporedite ime aktivnog prozora s prethodnim i ako se razlikuju, "učinite nešto". Sve je ovako jednostavno:

If ActiveWindow != %LastActiveWindow%
{
}

S obzirom na gore navedeno, provjerite razlikuje li se trenutni ActiveWindow ( != ) od vrijednosti pohranjene u varijabli LastActiveWindow (koja je inicijalno postavljena na prazno). Ako je tako, AHK će izvršiti kod između { i } , koji je trenutno prazan.

Postavite funkciju za usporedbu naslova aktivnog prozora i prethodnog prozora

Potrebno je pratiti i datum i vrijeme kako bi se izmjerilo vrijeme rada prozora. Zadržat će se različiti zapisnici za svaki dan, koji koriste datum u nazivu. Ne samo da će svaka promjena biti zabilježena, već i vrijeme kada se dogodila. Da biste to učinili, dodijelite različite formate vremena varijablama LogTime i LogFilename s:

FormatTime, LogTime,, HH:mm:ss
FormatTime, LogFilename,, yyyy-MMM-dd

Dodajte te retke između vitičastih zagrada u "If ActiveWindow..." tako da ih AHK pokrene kada otkrije promjenu prozora.

Dobijte trenutno vrijeme i dodijelite ga u dvije varijable različitih formata

4. Format podataka

Sada bilježimo vrijeme u dvije različito formatirane varijable, kao i naslov aktivnog prozora. Međutim, postoji mali problem: naslov prozora također može sadržavati neželjene znakove. Moguće je ukloniti sve nealfanumeričke znakove pomoću AHK-ove podrške za RegEx, s:

LogWindow := Regexreplace(ActiveWindow, "[^a-zA-Z0-9]", " ")

Imajući to na umu, "zamolimo" AHK da ukloni sve znakove iz varijable ActiveWindow koji ne odgovaraju onome što je u zagradama:

• mala slova
• Veliko slovo
• Brojke

Zatim dodijelite rezultat varijabli LogWindow.

Očistite naslov aktivnog prozora s RegExom

Sa svim postavljenim varijablama i svim prikupljenim vrijednim podacima, sada ste spremni za formatiranje datoteke dnevnika i njezinog sadržaja.

LogFilename = %LogFilename%_AppLog.md
LogFile = %LogPath%\%LogFilename%

Prethodno smo dodijelili trenutni datum varijabli LogFilename. Stoga u prvi redak dodajte "_AppLog.md" datumu da biste ga koristili kao naziv datoteke.

Postavite naziv datoteke dnevnika

U drugom redu kombinirajte varijablu LogPath , definiranu na početku kao odredište za datoteku dnevnika zajedno s nazivom datoteke. Njihova je kombinacija puni put do datoteke dnevnika, dodijeljen varijabli LogFile.

Dodijelimo ekvivalentnu vrijednost "prazan redak, vrijeme - naziv prozora, još dva prazna retka, razdjelnik i još jedan prazan redak, za dobru mjeru" varijabli FileContent.

FileContent = `n%LogTime% - %LogWindow%`n`n- - -`n

• Slovo "n" govori AHK-u da unese novi redak (ekvivalentno jednom pritisku Enter ).
• Tri crtice pojavit će se kao razdjelnik kada se prikazuju u pregledniku kompatibilnom s križićem prema dolje.
• "% LogTime%" i "% LogWindow%" su varijable koje pohranjuju naziv aktivnog prozora i vrijeme kada je otkriven.

Određuje sadržaj datoteke dnevnika

5. Ažurirajte datoteke

Definirali ste što želimo pisati u datoteku, kao i njen put i naziv datoteke. Sve što ostaje je stvarni, jednostavan tekst kako slijedi:

FileAppend, %FileContent%, %LogFile%

Dodajte sve u varijabli "FileContent" u datoteku "LogFile".

Upotrijebite AHK-ovu funkciju Append za ažuriranje datoteke dnevnika ili je napravite ispočetka

Funkcija "dodaj" će dodati "FileContent" datoteci ako postoji, ali će je također stvoriti ispočetka ako datoteka ne postoji.

Postoji još jedna završna izmjena: zamijenite sadržaj varijable LastActiveWindow trenutno aktivnim prozorom.

Umeće naslov trenutno aktivnog prozora u varijablu LastActiveWindow za buduće testiranje

Da biste to učinili, skripta bi trebala moći otkriti sljedeću promjenu prozora.

LastActiveWindow = %ActiveWindow%

I s tim posljednjim dodatkom, Windows logger je spreman! Spremite skriptu i pokrenite je. Zatim provjerite markdown datoteku, ova će se datoteka pojaviti u mapi datoteke skripte nakon 10 sekundi.

Windows log datoteka kreira se u istom direktoriju kao i skripta

Preuzmite kontrolu nad svojim vremenom

Dnevnik možete otvoriti bilo kojim uređivačem teksta. Međutim, izgledat će bolje ako ga otvorite u uređivaču kompatibilnom s markdown-om. Na snimci zaslona možete vidjeti zapisnik u popularnom uređivaču Typora.

Markdown datoteka koju je generirala skripta učitava se u Typora

To je jednostavan način da provjerite koje aplikacije koristite najviše vremena, a za korištenje je potreban samo alat poput Notepada.

Ako želite nešto "posebnije", uvijek možete "stilizirati" izlaz logera da umjesto toga stvorite CSV datoteku. Jednostavno je poput podešavanja varijable FileContent i ekstenzije stvorene datoteke. Zatim možete uvesti takve datoteke u aplikacije kao što su Excel, Google Calc ili čak u programe za praćenje vremena treće strane.

Kompletna skripta

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
; Variables
; ---------
AppLoggingRate = 10 ; Time interval (in seconds) between active window title captures.
SleepTime := AppLoggingRate * 1000
LogPath = %A_ScriptDir%
LastActiveWindow = 
; Logic
; -----
Loop
{
	Sleep %SleepTime%
	
	WinGetActiveTitle, ActiveWindow
	StoreActiveWindow = %ActiveWindow%
	
	If ActiveWindow != %LastActiveWindow%
	{
		FormatTime, LogTime,, HH:mm:ss
		FormatTime, LogFilename, , yyyy-MM-dd
		
		LogWindow := Regexreplace(ActiveWindow, "[^a-zA-Z0-9]", " ")
		
		LogFilename = %LogFilename%_AppLog.md
		LogFile = %LogPath%\%LogFilename%
		
		FileContent = `n%LogTime% - %LogWindow%`n`n- - -`n
		
		sleep 50
		
		FileAppend, %FileContent%, %LogFile%
		LastActiveWindow = %ActiveWindow%
	}
}
Exit