Hur man skapar en tidsspårningsapplikation på Windows med AutoHotKey

Du börjar ditt arbete varje dag tidigt så att du kan lösa allt under dagen. Sedan kollar du klockan och den är 03:00 men ditt arbete är fortfarande inte gjort. Så var har tiden tagit vägen?

Du kan använda en dedikerad tidsspårningsapp, men dessa kan vara komplicerade och frustrerande. Istället, varför inte skapa din egen enkla lilla app? Denna applikation kan spåra alla fönster du har använt under dagen. Du behöver bara AutoHotKey, en grundläggande ordbehandlare som Notepad, och ungefär en halvtimme. Låt oss börja!

Skapa ditt eget Windows-loggningsskript med AutoHotKey

Innan du börjar bör du installera AHK på din dator eftersom det kommer att fungera som en "parser" för skriptet. Det är verktyget som låter ditt skript "köras".

Obs : Du kan också kompilera skriptet efter att det är klart för att göra det till ett riktigt körbart program. Det ligger dock utanför ramen för denna artikel.

Ladda ner AutoHotKey från den officiella webbplatsen och installera den.

Välj Nytt > AutoHotKey-skript

Starta din favoritfilhanterare och gå till mappen där du vill lagra skriptet. Högerklicka sedan på en tom plats och välj New > AutoHotKey Script .

När det är klart är det dags att skriva själva manuset.

1. Identifiera nödvändiga variabler

Öppna skriptet i din favoritredigerare. Du kan använda något enkelt som Notepad som kommer med Windows, men artikeln kommer att använda Notepad++  för den här handledningen. Notepad++ är gratis och bättre anpassat för detta ändamål, så du bör prova det.

Observera att du inte bör använda några program som Word eller Google Docs, vilket kan påverka skriptets formatering. Använd en text- eller kodredigerare.

Skriptet kommer att innehålla lite grundläggande rekommenderad information om kompatibilitet och prestanda. Lämna dem som de är och starta manuset nedan.

Börjar med:

AppLoggingRate = 10 ; Time interval (in seconds) between active window title captures.
SleepTime := AppLoggingRate * 1000
LogPath = %A_ScriptDir%
LastActiveWindow =

Börja med att tilldela värdet "10" till AppLoggingRate , som kommer att användas för att beräkna tiden mellan fönsterloggningsförsök.

När den används med AHK:s Sleep-funktion är 1000 ungefär lika med en sekund. Så genom att multiplicera den med AppLogingRate kommer du att göra SleepTime-variabeln "lika med 10 sekunder".

LogPath är sökvägen som används för att lagra loggar. Exemplet använder värdet %A_ScriptDir% , vilket översätts till "katalogen där du kör skriptet". Du kan använda hela sökvägen till en annan mapp om du vill.

Slutligen, ställ in LastActiveWindow för att tömma och använd senare för att kontrollera om det aktiva fönstret har ändrats.

2. Övervaka aktiva fönster

Eftersom vi kontinuerligt vill övervaka vilket fönster som är aktivt och om det ändras, spela in titel och tid, måste vi använda en "loop".

Som namnet antyder körs en slinga kontinuerligt och upprepar samma funktion(er). Tack vare AHK:s enkla syntax är följande "kod" relativt lätt att förstå:

Loop
{
    Sleep %SleepTime%
    Msgbox, It Works!
}

Definiera en slinga genom att helt enkelt skriva ordet "loop" och sedan markera dess början med "{" och sluta med "}". Allt på raderna mellan "{" och "}" kommer att köras för alltid tills du avslutar skriptet.

Starta slingan genom att vänta ( Sleep ) under en tid som motsvarar variabeln SleepTime. Denna variabel gör tidskontrollen enklare. Istället för att redigera skriptet själv kan du "berätta" för det, via denna variabel, hur många sekunder varje slinga ska pågå.

Använd slutligen Message Box för att testa skriptet. Försök att spara och köra den (dubbelklicka på skriptfilen). Du kommer att se en meddelanderuta som säger "Det fungerar!" (skriptet fungerar) efter 10 sekunder.

Högerklicka på AHK:s ikon i Windows-facket och avsluta skriptet när du har fått tillräckligt med meddelanderutor. Gå sedan tillbaka till redigeraren och ersätt MsgBox- raden med:

WinGetActiveTitle, ActiveWindow

Detta är kommandot för att få titeln på det aktiva fönstret. Utelämna den extra "StoreActiveWindow" -raden som exemplet använde vid skript för testning.

Hämta titeln på det aktiva fönstret och lagra det i en variabel

3. Hämta aktuell tid och namn

Nu kommer kärnan i skriptlogiken. Jämför det aktiva fönstrets namn med det föregående, och om de skiljer sig, "gör något". Allt är så enkelt som detta:

If ActiveWindow != %LastActiveWindow%
{
}

Med tanke på ovanstående, kontrollera om det aktuella ActiveWindow skiljer sig ( != ) från värdet som lagrats i LastActiveWindow- variabeln (som ursprungligen var inställd på tom). Om så är fallet kommer AHK att köra koden mellan { och } , som för närvarande är tom.

Ställ in funktionen för att jämföra titeln på det aktiva fönstret och föregående fönster

Det är nödvändigt att spåra både datum och tid för att mäta upptiden för ett fönster. Olika loggar för varje dag, med datumet i deras namn kommer att behållas. Inte bara varje ändring utan tiden den inträffar kommer också att registreras. För att göra det, tilldela olika tidsformat till variablerna LogTime och LogFilename , med:

FormatTime, LogTime,, HH:mm:ss
FormatTime, LogFilename,, yyyy-MMM-dd

Lägg till dessa linjer mellan de lockiga klammerparenteserna i "If ActiveWindow..." , så att AHK kör dem när den upptäcker en fönsterändring.

Få aktuell tid och tilldela den i två variabler i olika format

4. Dataformat

Vi fångar nu tiden i två olika formaterade variabler, samt titeln på det aktiva fönstret. Det finns dock ett litet problem: fönstrets titel kan också innehålla oönskade tecken. Det är möjligt att ta bort alla icke-alfanumeriska tecken med hjälp av AHK:s stöd för RegEx, med:

LogWindow := Regexreplace(ActiveWindow, "[^a-zA-Z0-9]", " ")

Med detta i åtanke, låt oss "be" AHK att ta bort alla tecken från ActiveWindow-variabeln som inte matchar det som står inom parentes:

• Små bokstäver
• Stor bokstav
• Tal

Tilldela sedan resultatet till variabeln LogWindow.

Rensa upp det aktiva fönstrets titel med RegEx

Med alla variabler inställda och all värdefull data insamlad är du nu redo att formatera loggfilen och dess innehåll.

LogFilename = %LogFilename%_AppLog.md
LogFile = %LogPath%\%LogFilename%

Tidigare tilldelade vi det aktuella datumet till variabeln LogFilename. För den första raden lägger du därför till "_AppLog.md" till datumet för att använda det som filnamn.

Ställ in loggfilens namn

På den andra raden kombinerar du variabeln LogPath , definierad i början som destination för loggfilen tillsammans med filnamnet. Deras kombination är loggfilens fullständiga sökväg, tilldelad variabeln LogFile.

Låt oss tilldela motsvarande värde för "tom rad, tid - fönstrets namn, ytterligare två tomma rader, en avdelare och en annan tom rad, för gott skull" till variabeln FileContent.

FileContent = `n%LogTime% - %LogWindow%`n`n- - -`n

• Bokstaven "n" talar om för AHK att ange en ny rad (motsvarande att trycka på Enter en gång).
• Tre streck kommer att visas som en avgränsare när de visas i en korsadkompatibel visningsprogram.
• "% LogTime%" och "% LogWindow%" är variabler som lagrade namnet på det aktiva fönstret och tiden då det upptäcktes.

Bestämmer innehållet i loggfilen

5. Uppdatera filer

Du har definierat vad vi vill skriva till filen, samt dess sökväg och filnamn. Allt som återstår är den faktiska, enkla texten som följer:

FileAppend, %FileContent%, %LogFile%

Lägg till allt i "FileContent" -variabeln till "LogFile"-filen.

Använd AHK:s Append-funktion för att uppdatera loggfilen eller skapa en från grunden

Funktionen "lägg till" kommer att lägga till "FileContent" till filen om den finns, men kommer också att skapa den från början om filen inte finns.

Det finns en sista justering: ersätt innehållet i LastActiveWindow- variabeln med det för närvarande aktiva fönstret.

Infogar titeln på det aktuella aktiva fönstret i variabeln LastActiveWindow för framtida testning

För att göra detta bör skriptet kunna upptäcka nästa fönsterändring.

LastActiveWindow = %ActiveWindow%

Och med det sista tillägget är windowsloggern klar! Spara skriptet och kör det. Kontrollera sedan markdown-filen, den här filen kommer att visas i skriptfilmappen efter 10 sekunder.

Windows-loggfilen skapas i samma katalog som skriptet

Ta hand om din egen tid

Du kan öppna loggfilen med vilken textredigerare som helst. Det kommer dock att se bättre ut om du öppnar det i en markdown-kompatibel redigerare. På skärmdumpen kan du se loggen i den populära Typora-redigeraren.

Markdown-filen som genereras av skriptet laddas i Typora

Det är ett enkelt sätt att kontrollera vilka appar du har använt mest tid och kräver bara ett verktyg som Anteckningar för att använda.

Om du vill ha något "mer speciellt" kan du alltid "styla" loggerens utdata för att skapa en CSV-fil istället. Det är lika enkelt som att justera FileContent- variabeln och förlängningen av den skapade filen. Du kan sedan importera sådana filer till applikationer som Excel, Google Calc eller till och med tredjeparts tidsspårare.

Komplett manus

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
; Variables
; ---------
AppLoggingRate = 10 ; Time interval (in seconds) between active window title captures.
SleepTime := AppLoggingRate * 1000
LogPath = %A_ScriptDir%
LastActiveWindow = 
; Logic
; -----
Loop
{
	Sleep %SleepTime%
	
	WinGetActiveTitle, ActiveWindow
	StoreActiveWindow = %ActiveWindow%
	
	If ActiveWindow != %LastActiveWindow%
	{
		FormatTime, LogTime,, HH:mm:ss
		FormatTime, LogFilename, , yyyy-MM-dd
		
		LogWindow := Regexreplace(ActiveWindow, "[^a-zA-Z0-9]", " ")
		
		LogFilename = %LogFilename%_AppLog.md
		LogFile = %LogPath%\%LogFilename%
		
		FileContent = `n%LogTime% - %LogWindow%`n`n- - -`n
		
		sleep 50
		
		FileAppend, %FileContent%, %LogFile%
		LastActiveWindow = %ActiveWindow%
	}
}
Exit